home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
TPUG - Toronto PET Users Group
/
TPUG Users Group CD
/
TPUG Users Group CD.iso
/
C64
/
A-Monthly Disks
/
(c)abe.d64
/
psi
(
.txt
)
< prev
next >
Wrap
Commodore BASIC
|
2007-02-04
|
5KB
|
205 lines
10 REM ***********************
20 REM *** PSI ***
30 REM *** A PROGRAM BY ***
40 REM ***JEFFREY S. TOLLEY***
50 REM *** Q-LINK NAME: ***
60 REM *** JEFF T13 ***
70 REM ***********************
80 REM TITLE SCREEN
90 PRINT"[156][147]":POKE53280,15:POKE53281,15
100 REM ***BORDER FLASH***
110 FORJ=679 TO 693:READ K:POKEJ,K:NEXT
120 FORX=1TO10:PRINT:NEXTX
130 PRINTTAB(5)" [146][183][183][183][208]"
140 PRINTTAB(5)" [146] [167]"
150 PRINTTAB(5)" [146] [167]"
160 PRINTTAB(5)" [146][175][175][175][186]"
170 PRINTTAB(5)" [146]"
180 PRINTTAB(5)" [146]"
190 PRINTTAB(5)" [146]"
200 FORX=1TO500:NEXTX:PRINT"[145][145][145][145][145][145][145][145]"
210 PRINTTAB(15)" [146][183][183][183][208]"
220 PRINTTAB(15)" [146]"
230 PRINTTAB(15)" [223][146]"
240 PRINTTAB(15)" [146]"
250 PRINTTAB(15)" [223] [146]"
260 PRINTTAB(15)" [146]"
270 PRINTTAB(15)"[204][175][175][175] [146]"
280 FORX=1TO500:NEXTX:PRINT"[145][145][145][145][145][145][145][145]"
290 PRINTTAB(25)"[207][183][183] [146][183][183][208]"
300 PRINTTAB(25)" [146]"
310 PRINTTAB(25)" [146]"
320 PRINTTAB(25)" [146]"
330 PRINTTAB(25)" [146]"
340 PRINTTAB(25)" [146]"
350 PRINTTAB(25)"[204][175][175] [146][175][175][186]"
360 FORX=1TO500:NEXTX
370 FORX=1TO16:PRINT:NEXTX
380 FORX=1TO1000:NEXTX:PRINT"[145][145][145][145][145][145][145][145][145][145][145]"TAB(19)"BY":PRINT:PRINT:PRINT
390 FORX=1TO500:NEXTX
400 PRINTTAB(11)"JEFFREY S. TOLLEY":FORX=1TO1000:NEXTX
410 PRINT:PRINT:PRINT:PRINTTAB(14)"<HIT ANY KEY>":SYS679:PRINT"[147]":ZZ$=""
420 GOSUB1430
430 PRINTCHR$(14)
440 FORX=1TO10:PRINT:NEXTX:PRINTTAB(5)"[196]O YOU WANT INSTRUCTIONS? (Y/N)"
450 GET ZZ$:IFZZ$=""THEN450
460 IF ZZ$<>"Y"THEN830
470 PRINT"[147][212]HIS PROGRAM IS A RANDOM-EVENT GENERATOR";
480 PRINT"THAT MAY BE USED TO TEST ESP ABILITIES,"
490 PRINT"SPECIFICALLY, PRECOGNITIVE ABILITY, OR"
500 PRINT"THE ABILITY TO SEE INTO THE FUTURE.":PRINT
510 PRINT"[215]HILE NOT AS SOPHISTICATED, THIS"
520 PRINT"PROGRAM IS A SCALED-DOWN VERSION OF THE"
530 PRINT"COMPUTER TESTS USED BY ACTUAL PSYCHIC"
540 PRINT"RESEARCHERS.":GOSUB1430
550 PRINT"[198]IRST, YOU'LL BE SHOWN FIVE PATTERNS."
560 PRINT"[217]OU'LL TAKE SEVERAL TURNS GUESSING WHAT"
570 PRINT"PATTERN THE COMPUTER WILL RANDOMLY "
580 PRINT"DISPLAY NEXT. [193]FTER YOU'RE DONE, THE "
590 PRINT"RESULTS ARE DISPLAYED AND A SIMPLE"
600 PRINT"EVALUATION OF YOUR [197][211][208] (OR [208][211][201]) "
610 PRINT"ABILITIES IS MADE. [212]HIS IS DONE BY "
620 PRINT"COMPARING THE NUMBER OF CORRECT GUESSES"
630 PRINT"YOU MAKE TO THE NUMBER OF ANSWERS YOU"
640 PRINT"HAVE THE PROBABILITY OF GUESSING "
650 PRINT"CORRECTLY AT RANDOM.":GOSUB1430
660 PRINT"[212]WO HINTS TO GET THE MOST OUT OF THE "
670 PRINT"GAME: 1) [212]HE HIGHER NUMBER OF EVENTS YOU";
680 PRINT"CHOOSE, THE BETTER THE CHANCES OF"
690 PRINT"GETTING RESULTS THAT ARE ACCURATE AND"
700 PRINT"NOT PRODUCED BY CHANCE. 2) [215]HEN YOU "
710 PRINT"READ THE RESULTS, REMEMBER THAT A NUMBER";
720 PRINT"OF CORRECT GUESSES SIGNIFICANTLY LOWER"
730 PRINT"THAN THE PROBABILITY OF CORRECT ANSWERS"
740 PRINT"CAN ALSO INDICATE PSYCHIC ABILITIES,"
750 PRINT"ESPECIALLY IN THOSE PEOPLE WHO ARE"
760 PRINT"SKEPTICAL OF, OR NON-BELIEVERS IN,"
770 PRINT"PSYCHIC PHENOMENA."
780 PRINT:PRINT"[201]F YOU HAVE ANY COMMENTS, PRAISE, "
790 PRINT"SUGGESTIONS OR INFO ABOUT SIMILAR "
800 PRINT"PROGRAMS, PLEASE ADDRESS YOUR [197]-MAIL TO"
810 PRINT"[202]EFF [212]13[146]."
820 PRINT:PRINT"[197]NJOY YOUR GAME!":GOSUB1430
830 REM THE GAME
840 ZZ$=""
850 PRINT"[147]":FORX=1TO10:PRINT:NEXTX
860 INPUT"[200]OW MANY EVENTS? (10/20/50/100) ";EV
870 IF EV=10THEN920
880 IF EV=20THEN920
890 IF EV=50THEN920
900 IF EV=100THEN920
910 GOTO860
920 PRINT:PRINT:PRINT"[207]KAY. [204]ET'S LOOK AT ALL THE PATTERNS.":GOSUB1430
930 GOSUB1470:GOSUB1430
940 GOSUB1580:GOSUB1430
950 GOSUB1690:GOSUB1430
960 GOSUB1810:GOSUB1430
970 GOSUB1910:GOSUB1430:PRINTCHR$(14)
980 FOR L=1TO EV
990 PRINTCHR$(14)
1000 PRINT"[147][197]VENT #"L"[157] [195]ORRECT [199]UESSES:"CG"[157] [146]"
1010 PRINT
1020 PRINTTAB(6)"[215]HICH PATTERN WILL BE NEXT?"
1030 POKE646,7:PRINT:PRINTTAB(15)"1) [211]QUARE"
1040 POKE646,8:PRINT:PRINTTAB(15)"2) [212]RIANGLE"
1050 POKE646,14:PRINT:PRINTTAB(15)"3) [211]TAR"
1060 POKE646,13:PRINTTAB(15)"4) [208]LUS":POKE646,1
1070 POKE646,1:PRINTTAB(15)"5) [196]IAMONDS"
1080 POKE646,4:PRINT:PRINT:INPUT" [197]NTER 1-5 ";GU
1090 IF GU<1 OR GU>5 THEN1000
1100 PRINT"[147]"
1110 PA=INT(RND(0)*5+1)
1120 IF PA=GU THENCG=CG+1
1130 IF PA=1 THEN GOSUB1470
1140 IF PA=2 THEN GOSUB1580
1150 IF PA=3 THEN GOSUB1690
1160 IF PA=4 THEN GOSUB1810
1170 IF PA=5 THEN GOSUB1910
1180 IF PA=GU THENPRINTTAB(12)"YOU GUESSED RIGHT![146]":GOTO1200
1190 PRINTTAB(13)"GUESS INCORRECT[146]":GU=0
1200 IFPA<>GUTHENGOSUB1430:GOTO1220
1210 PRINTTAB(14)"<HIT ANY KEY>":SYS679:FORVV=1TO500:NEXTVV:GU=0:PRINT"[147]"
1220 NEXT L
1230 PRINTCHR$(14)
1240 PRINTTAB(15)"[197][214][193][204][213][193][212][201][207][206][146]":PRINT:PRINT:PRINT
1250 PRINT"[206]UMBER OF EVENTS:"EV:PRINT
1260 PN=EV*.2
1270 PRINT"[208]ROBABLE NUMBER OF CORRECT GUESSES:"PN:PRINT:PRINT:PRINT
1280 PRINT"[217]OU MADE"CG"CORRECT GUESSES.":PRINT
1290 DF=CG-PN
1300 ST$="ABOVE"
1310 IF DF<0 THENST$="BELOW"
1320 DF=ABS(DF)
1330 PRINT"[212]HAT'S"DF"GUESSES "ST$" CHANCE."
1340 PC=100/EV:SI=PC*DF
1350 PRINT
1360 PRINT"[217]OUR PSI RATING IS"SI"[157]%[146]"
1370 PRINT:PRINT
1380 PRINTTAB(11)"[208]LAY AGAIN? (Y/N)"
1390 GET ZZ$:IFZZ$=""THEN1390
1400 IF ZZ$="N"THEN1420
1410 CLR:GOTO830
1420 PRINT:PRINT:PRINTTAB(7)"[212]HANK YOU FOR PLAYING [208][211][201]!":PRINT:PRINT:END
1430 REM *GET ROUTINE*
1440 PRINT:PRINT:PRINT:PRINTTAB(14)"<HIT ANY KEY>"
1450 GET ZZ$:IF ZZ$=""THEN1450
1460 PRINT"[147]":RETURN
1470 REM SQUARE
1480 PRINTCHR$(142)
1490 PRINT:PRINT"[158]"
1500 PRINTTAB(17)"[207][183][183][183][183][183][208]"
1510 PRINTTAB(17)"[165] [170]"
1520 PRINTTAB(17)"[165] [170]"
1530 PRINTTAB(17)"[165] [167]"
1540 PRINTTAB(17)"[165] [167]"
1550 PRINTTAB(17)"[204][175][175][175][175][175][186]"
1560 PRINT:PRINT:PRINTTAB(17)"SQUARE":PRINT:PRINT"[156]"
1570 RETURN
1580 REM TRIANGLE
1590 PRINTCHR$(142)
1600 PRINT:PRINT:POKE646,8
1610 PRINTTAB(17)" [146][169]"
1620 PRINTTAB(17)" [146][169]"
1630 PRINTTAB(17)" [146][169]"
1640 PRINTTAB(17)" [146][169]"
1650 PRINTTAB(17)" [146][169]"
1660 PRINTTAB(17)"[169]"
1670 PRINT:PRINT:PRINTTAB(17)"TRIANGLE":PRINT:PRINT"[156]"
1680 RETURN
1690 REM STAR
1700 PRINTCHR$(142)
1710 PRINT:PRINT:POKE646,14
1720 PRINTTAB(17)"* * *"
1730 PRINTTAB(17)" * * *"
1740 PRINTTAB(17)" ***"
1750 PRINTTAB(17)"*******"
1760 PRINTTAB(17)" ***"
1770 PRINTTAB(17)" * * *"
1780 PRINTTAB(17)"* * *"
1790 PRINT:PRINT:PRINTTAB(18)"STAR":PRINT:PRINT"[156]"
1800 RETURN
1810 REM PLUS
1820 PRINTCHR$(142)
1830 PRINT:PRINT:POKE646,13
1840 PRINTTAB(17)" [194] "
1850 PRINTTAB(17)" [194]"
1860 PRINTTAB(17)"[195][195][195][219][195][195][195]"
1870 PRINTTAB(17)" [194]"
1880 PRINTTAB(17)" [194]"
1890 PRINT:PRINT:PRINTTAB(18)"PLUS":PRINT:PRINT"[156]"
1900 RETURN
1910 REM DIAMONDS
1920 PRINTCHR$(142)
1930 PRINT:PRINT""
1940 PRINTTAB(17)"[206][205][206][205][206][205][206][205]"
1950 PRINTTAB(17)"[205][206][205][206][205][206][205][206]"
1960 PRINTTAB(17)"[206][205][206][205][206][205][206][205]"
1970 PRINTTAB(17)"[205][206][205][206][205][206][205][206]"
1980 PRINTTAB(17)"[206][205][206][205][206][205][206][205]"
1990 PRINTTAB(17)"[205][206][205][206][205][206][205][206]"
2000 PRINT:PRINT:PRINTTAB(17)"DIAMONDS":PRINT:PRINT"[156]"
2010 RETURN
2020 REM ***BORDER FLASH DATA***
2030 DATA 172,032,208,202,142,032,208,165
2040 DATA 198,240,248,140,032,208,096